excel技能：在主工作表中汇总多个工作表中满足条件的值-英雄云拓展知识分享

我们可能熟习使用INDEX、SMALL等在给订单列或单行数组的情形下，返回满足一个或多个条件的值的列表。这是一项标准的公式技术。

在《Excel公式练习32：将包括空单元格的多行多列单元格区域转换成单独的列并去掉空单元格》中，我们述了一种方法，给定由多个列组成的单元格区域，从该区域返回由所有非空单元格组成的单个列。可以很容易地验证，在该公式中的单个条件可以扩大到多个条件，因此，这种情况下，我们现在有了从一维数组和2维数组中生成单列列表的方法。

那末，可以更进一步吗，我们将继续深入。“3维”是常常利用于Excel中特定公式的通用术语，这些公式不但可以对单列或单行进行操作，也能够对由多列或多行组成的单元格区域进行操作，还可以行之有效的地对多个工作表进行操作。

本文提供了一种方法，在给定一个或多个相同布局的工作表的情形下，可以创建另外一个“主”工作表，该工作表仅由满足特定条件的所有工作表中的数据组成。并且，这里不使用VBA，仅使用公式。

假定我们想从下面3个工作表中整理数据：

工作表Sheet1：

图1

工作表Sheet2：

图2

工作表Sheet3：

图3

想要创建一个主工作表Master，其数据来源于上面3个工作表中列D中的值为“Y”的数据：

图4

解决方案

首先，定义内涵下面两个名称：

名称：Sheet3

援用位置：={“Sheet1″,”Sheet2″,”Sheet3”}

名称：Arry1

援用位置：=MMULT(0+(ROW(INDIRECT(“1:”&COUNTA(Sheets)))>=TRANSPOSE(ROW(INDIRECT(“1:”&COUNTA(Sheets))))),TRANSPOSE(COUNTIF(INDIRECT(“‘”&Sheets&”‘!D2:D10″),”Y”)))

可以针对实际情况，修改工作表列表和数据范围（D2:D10）。

在工作表Master的单元格G1中，输入下面的公式：

=SUMPRODUCT(COUNTIF(INDIRECT(“‘”&Sheets&”‘!D2:D10″),”Y”))

在工作表Master的单元格A2中输入下面的数组公式：

=IF(ROWS($1:1)>$G$1,””,INDEX(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!A2:F10”),SMALL(IF(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!D2:D10″)=”Y”,ROW(INDIRECT(“1:”&$G$1))),IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))),COLUMNS($A:A)))

向下和向右拖放公式至适合的位置。

工作原理

先看看相对简单的单元格G1中的公式，该公式用于肯定返回结果的数量：

=SUMPRODUCT(COUNTIF(INDIRECT(“‘”&Sheets&”‘!D2:D10″),”Y”))

如果不熟习跨多个工作表使用公式的技术，那末应记下使用INDIRECT的这类公式构造，由于它实际上是我们履行此类计算的唯一方法。上述公式转换为：

=SUMPRODUCT(COUNTIF(INDIRECT(“‘”&{“Sheet1″,”Sheet2″,”Sheet3″}&”‘!D2:D10″),”Y”))

然后，将这组代表工作表名称的文本字符串的两端连接，在后面是所使用的工作表区域（D2:D10），在前面用单个撇号连接。虽然在工作表的名称中不包括空格的情形下，其实不需要这样，但是这样做将更好更通用。这样，公式转换为：

=SUMPRODUCT(COUNTIF(INDIRECT({“‘Sheet1’!D2:D10″,”‘Sheet2’!D2:D10″,”‘Sheet3’!D2:D10″}),”Y”))

由于COUNTIF函数能够操作3维单元格区域，并且SUMPRODUCT函数提供了必要的强迫转换，使得INDIRECT函数返回一组单元格援用，而不单单是一个，因此公式转换为：

=SUMPRODUCT({3,2,1})

其中数组的值由3、2、1组成，与工作表Sheet1、Sheet2、Sheet3的列D中包括“Y”的数量一致。该公式的最后结果为：

6

接下来，看看单元格A2中的主公式：

=IF(ROWS($1:1)>$G$1,””,INDEX(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!A2:F10”),SMALL(IF(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!D2:D10″)=”Y”,ROW(INDIRECT(“1:”&$G$1))),IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))),COLUMNS($A:A)))

在IF函数中的前半部份很简单，如果拖放的行数超过了可能取得的结果数量，则为空。

在公式中使用了定义内涵的名称Arry1：

=MMULT(0+(ROW(INDIRECT(“1:”&COUNTA(Sheets)))>=TRANSPOSE(ROW(INDIRECT(“1:”&COUNTA(Sheets))))),TRANSPOSE(COUNTIF(INDIRECT(“‘”&Sheets&”‘!D2:D10″),”Y”)))

这类公式构造可以行之有效的地动态生成汇总小计，并且是使用标准的SUBTOTA/OFFSET函数组合的替换方法。

顺次看看传递给MMULT函数的数组。第一个是：

0+(ROW(INDIRECT(“1:”&COUNTA(Sheets)))>=TRANSPOSE(ROW(INDIRECT(“1:”&COUNTA(Sheets)))))

转换为：

0+(ROW(INDIRECT(“1:”&3))>=TRANSPOSE(ROW(INDIRECT(“1:”&3))))

转换为：

0+({1;2;3}>=TRANSPOSE({1;2;3}))

转换为：

0+({1;2;3}>={1,2,3})

两个正交数组进行比较，一个是3行1列，一个是1行3列，得到一个3行3列的数组，该数组由9个TRUE/FALSE值组成：

0+({TRUE,FALSE,FALSE;TRUE,TRUE,FALSE;TRUE,TRUE,TRUE})

转换为1/0值组成的数组：

{1,0,0;1,1,0;1,1,1}

另外一个传递给MMULT函数的数组是：

TRANSPOSE(COUNTIF(INDIRECT(“‘”&Sheets&”‘!D2:D10″),”Y”))

转换为：

TRANSPOSE({3,2,1})

得到：

{3;2;1}

因此，这种情况下，MMULT函数变成：

MMULT({1,0,0;1,1,0;1,1,1},{3;2;1})

结果是：

{3;5;6}

使用Arry1的值来替换主公式中的相应部份，先看看公式中的：

INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!A2:F10”)

转换为：

INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,{3;5;6}>=1,0))&”‘!A2:F10”)

转换为：

INDIRECT(“‘”&INDEX(Sheets,1)&”‘!A2:F10”)

转换为：

INDIRECT(“‘”&”Sheet1″&”‘!A2:F10”)

转换为：

INDIRECT(“‘Sheet1’!A2:F10”)

因此，这种情况下，可以看到，对A2中的公式，将返回Sheet1。举例来看，如果解构单元格A5中的公式，那末公式中的MATCH构造将以下所示：

MATCH(TRUE,Arry1>=ROWS($1:4),0)

唯一产生变化的是援用ROWS($1:4)而不是ROWS($1:1)，结果转换为：

MATCH(TRUE,{3;5;6}>=4,0)

得到2，这样将援用工作表Sheet2。

事实上，该技术的关键为：经过生成动态汇总小计数量的数组，该小计数量由来自每一个工作表中符合条件（即在列D中的值为“Y”）的行数组成，然后将公式所在单元格相对行数与该数组相比较，以便行之有效的地肯定公式所在行中要指定的工作表。因此，这种情况下，主公式中的子句：

INDEX(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!A2:F10”),SMALL(IF(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!D2:D10″)=”Y”,ROW(INDIRECT(“1:”&$G$1))),IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))),COLUMNS($A:A))

可转换为：

INDEX(Sheet1!A2:F10,SMALL(IF(Sheet1!D2:D10=”Y”,ROW(INDIRECT(“1:”&$G$1))),IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))),COLUMNS($A:A))

先看看上面公式中的SMALL函数部份：

IF(Sheet1!D2:D10=”Y”,ROW(INDIRECT(“1:”&$G$1)))

转换为：

IF({“Y”;0;”Y”;”Y”;0;0;0;0;0}=”Y”,ROW(INDIRECT(“1:”&6)))

转换为：

IF({TRUE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE},{1;2;3;4;5;6})

得到：

{1;FALSE;3;4;FALSE;FALSE;FALSE;FALSE;FALSE}

这里，可以看到数组中的1、3和4对应于工作表Sheet1列D中为“Y”的相对行号。现在要做的就是将该数组传递给SMALL函数并肯定参数k，这实际上是全部解决方案中最难的部份，由于与我们将这类构造利用于由单列组成的数组不同（举例来看，在这类情况下，对连续行，可以简单地将参数k增加1），而这里必须斟酌：当要求Sheet2返回值时，和要求Sheet3返回值时，该参数将被“重置”为1。为此，就某些情况而言，这里使用：

IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))

为理解这个公式构造是如何工作的，我们可暂时将其作为独立的数组公式，输入到某单元格中，然后向下拖放以了解其生成的值。事实上，将该公式从A2向下拖至A7，可转换为：

IFERROR(1+{1,2,3,4,5,6}-LOOKUP({1,2,3,4,5,6},1+Arry1),{1,2,3,4,5,6})

转换为：

IFERROR(1+{1,2,3,4,5,6}-LOOKUP({1,2,3,4,5,6},1+{3;5;6}),{1,2,3,4,5,6})

转换为：

IFERROR(1+{1,2,3,4,5,6}-{#N/A,#N/A,#N/A,4,4,6},{1,2,3,4,5,6})

转换为：

=IFERROR({#N/A,#N/A,#N/A,1,2,1},{1,2,3,4,5,6})

得到：

{1,2,3,1,2,1}

正是我们需要的参数k的值，即在工作表Sheet1中匹配第1、第2和第3小的行，在工作表Sheet2中匹配第1和第2小的行，在工作表Sheet3中匹配第1小的行。

现在，回到主公式中的子句：

INDEX(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!A2:F10”),SMALL(IF(INDIRECT(“‘”&INDEX(Sheets,MATCH(TRUE,Arry1>=ROWS($1:1),0))&”‘!D2:D10″)=”Y”,ROW(INDIRECT(“1:”&$G$1))),IFERROR(1+ROWS($1:1)-LOOKUP(ROWS($1:1),1+Arry1),ROWS($1:1))),COLUMNS($A:A))

可转换为：

INDEX(Sheet1!A2:F10,SMALL({1;FALSE;3;4;FALSE;FALSE;FALSE;FALSE;FALSE},1),COLUMNS($A:A))

转换为：

INDEX(Sheet1!A2:F10,1,COLUMNS($A:A))

COLUMNS($A:A)使得公式向右拖放时，可以为INDEX函数的参数column_num提供适合的值。在单元格A2中，COLUMNS($A:A)的值等于1，因此公式转换为：

INDEX(Sheet1!A2:F10,1,1)

即工作表Sheet1中单元格A2的值。